This article describe howto get a 1-wire humidity probe to work with Nagios or op5 Monitor.

In an earlier article I have described a 1-wire temperature plugin.

Pre requriments

To get it working you need:

• 1-wire humidity probe i.e. this, it is based on DS2438 & HIH-4000
• A working owfs installation, instructions can be found here
• Nagios or op5 Monitor

check_1-wirehumid

The plugin is written in perl and version 1.0 can be downloaded here

#!/usr/bin/perl -w
#
# Check humidity of 1Wire device
# Requires use of Fuse and owfs
#
#
# By Peter Andersson
# peter@it-slav.net
# http://www.it-slav.net/blogs/?p=802
# Licence GPLv2
# Version 1.0

use strict;
use Getopt::Std;
use OW;

my $owserver = "127.0.0.1:3001";
my(%ERRORS) = ( OK=>0, WARNING=>1, CRITICAL=>2, UNKNOWN=>3 );

my $humidity;
my $status=$ERRORS{OK};;
my $message;

my $debug_flag=0;

our($opt_c, $opt_w, $opt_W, $opt_C, $opt_h, $opt_o, $opt_i);

getopts("w:W:c:C:ho:i:");

sub printhelp () {
	print "Usage: check_1-wirehumid [-h] -c lowhumidcritical -w lowhumidwarning -W highhumidwarning -C highhumidcritical -i id [-o owserver:port]\n";
	print "-h Help, this text\n-c num Critical threshold for low humidity\n-w num Warning threshold for low humidity\n";
	print "-W num Warning threshold for high humidity\n-C num Critical threshold for high humidity\n";
	print "-o <name|ip>:port, Servername of 1-wire server and portnumber the owserver use, default 127.0.0.1:3001\n";
	print "-i 1-wire ID, i.e. 10.DEF05F01080015\n";
	print "\n\t\tby Peter Andersson\n\t\tpeter\@it-slav.net\n\t\thttp://www.it-slav.net/blogs/?p=802\n";
	exit $status;
}

#sanity check
if (!$opt_c||!$opt_w||!$opt_W||!$opt_C||$opt_h) {
	$status= $ERRORS{UNKNOWN};
	&printhelp;
} elsif ($opt_c > $opt_w) {
	print "Critical low threshold must be higher or equal to warning low threshold\n";
	$status= $ERRORS{UNKNOWN};
	&printhelp;
} elsif ($opt_w > $opt_W || $opt_c > $opt_C) {
	print "Lower tresholds must be lower then higher thresholds\n";
	$status= $ERRORS{UNKNOWN};
	&printhelp;
} elsif ($opt_C < $opt_W) {
	print "Higher critical threshold must be higher or equal to higher warning threshold\n";
	$status= $ERRORS{UNKNOWN};
	&printhelp;
}

if ($opt_o) {
	$owserver = $opt_o;
}

unless(OW::init($owserver)) {
	$status = $ERRORS{CRIT};
	$message = "OWServer not running at $owserver\n";
	exit $status;
}
$humidity = OW::get("$opt_i/humidity");
$humidity =~ s/^\s*(.*?)\s*$/$1/; #remove whitespaces
unless (($humidity =~ /^-?(?:\d+(?:\.\d*)?|\.\d+)$/) || ($humidity =~ /^[+-]?\d+$/)) #check that it is an integer or decimal returned
{
	$message="Did not got an integer or a decimal from humidity probe";
        $status=$ERRORS{CRITICAL};
}
$humidity = sprintf("%.0f", $humidity);

if ($debug_flag) {
	print "opt_c:$opt_c opt_w:$opt_w opt_W:$opt_W opt_C:$opt_C opt_h:$opt_h owserver:$owserver opt_i:$opt_i Humidity:$humidity\n";
}

if ($humidity <= $opt_c) {
	$status=$ERRORS{CRITICAL};
	$message="CRITICAL";
} elsif ($humidity > $opt_c && $humidity <= $opt_w) {
	$status=$ERRORS{WARNING};
	$message="WARNING";
} elsif ($humidity >  $opt_w && $humidity <  $opt_W) {
	$status=$ERRORS{OK};
	$message="OK";
} elsif ($humidity >= $opt_W && $humidity < $opt_C) {
	$status=$ERRORS{WARNING};
	$message="WARNING";
} elsif ($humidity >= $opt_C) {
	$status=$ERRORS{CRITICAL};
	$message="CRITICAL";
} else { #This should never happend
	$status=$ERRORS{UNKNOWN};
	$message="UNKNOW";
}

print "$message: $humidity \%\|humidity=$humidity\%\;$opt_c;$opt_w;$opt_W;$opt_C\n";
exit $status;

Test the plugin by run:

[root@op5 custom]# ./check_1-wirehumid -c 10 -w 20 -W 90 -C 95 -i 26.D7EABC000000
OK: 31 %|humidity=31%;10;20;90;95

So I have 31 % humidity.

Nagios config files

In checkcommands.cfg, define check_1-wirehumid

# command 'check_1-wirehumid'
define command{
    command_name                   check_1-wirehumid
    command_line                   $USER1$/custom/check_1-wirehumid -c $ARG1$ -w $ARG2$ -W$ARG3$ -C$ARG4$ -i $ARG5$ -o $ARG6$
    }

In serviced.cfg, define the check. I have a service group called Environemnt where all my Environments probes are.

# service 'Washroom Humidity'
define service{
    use                            default-service
    host_name                      monitor
    service_description            Washroom Humidity
    check_command                  check_1-wirehumid!10!20!80!90!26.D7EABC000000!127.0.0.1:3001
    servicegroups                  Environment
    contact_groups                 it-slav_msn,it-slav_mail,call_it-slav
    }

Screenshots

This is a screen shoot from op5 Monitor showing my Servicegroup Environment.

If you have op5 Monitor or PNP for Nagios, graphs like this will automatically be created. Note that I had a shower 6.20 and the humidity went from approx 25% to 95% in a couple of minutes.

It-slav.net provides temperature measurement for STHLM/Huddinge area in Sweden to the very popular site temperatur.nu

The measurment is done by a 1-wire temperature probe DS18S20.

The script that collects the temperature and stores it in a file that is presented as a webpage, the webpage is polled regularly by temperatur.nu

#!/usr/bin/perl
 #
 # rrd_tempsensor.pl

#use lib qw(/usr/local/rrdtool-1.2.15/lib/perl);
 use RRDs;
 use OW;

# define location of rrdtool databases
 my $rrd = '/root/owfs/script/rrd_db';
 # define location of images
 my $img = '/home/peter/public_html/temps';

# process data for each interface (add/delete as required)
 &ProcessSensor(0, "Temperatur_Huddinge", "op5.mynet",3001,"10.DEF05F010800");

sub ProcessSensor
 {
 # process sensor
 # inputs: $_[0]: sensor number (ie, 0/1/2/etc)
 #         $_[1]: sensor description
 print "number:$_[0] desc:$_[1], server:$_[2] port:$_[3], id: $_[4]\n";
 my $owserver = "$_[2]:$_[3]";

unless(OW::init($owserver)) {
 $status = $ERRORS{CRIT};
 $message = "OWServer not running at $owserver\n";
 exit $status;
 }

# get temperature from sensor
 my $handle = OW::get("$_[4]/temperature");
 #    print "handle=$handle\n";
 $handle =~ s/^\s*(.*?)\s*$/$1/;
 ## Check if input is an integer or decimal
 unless (($handle =~ /^-?(?:\d+(?:\.\d*)?|\.\d+)$/) || ($handle =~ /^[+-]?\d+$/))
 {
 print "Not an integer or a decimal\n";
 return($ERRORS{CRITICAL});
 }

$temp=$handle;
 # remove eol chars
 chomp($temp);

print "sensor $_[0]: $temp degrees C\n";

# check for error code from temp sensor
 if (int $temp eq 85)
 {
 print "failed to read value from sensor $_[0]\n";
 }
 else
 {
 #Create webpage
 open WEBPAGE, ">$img/$_[1]"
 or die "Cannot create $img/$_[1]: $!";
 print WEBPAGE "$temp\n";
 }
 }

Links:

• http://www.temperatur.nu temperatures from alot of places in Sweden
• My info page at temperatur.nu
• Temperature graphs made by data from me
• The “webpage” that the script  create
• More information about 1-wire at this blog

I use it to get a quick overview how my DataCenter is doing. When the LCD display is flashing something has either WARNING or CRITICAL status.

Step by step guide

1. Get the Hardware, I bought it from http://shop.temperatur.nu.

LCD controller http://shop.temperatur.nu/1wire-lcd-kontroller-p-74.html

LCD Display http://shop.temperatur.nu/hd44780-20×4-character-lcd-display-bla-bakgrundsbelysning-p-75.html

2. Make sure that your 1-wire bus works

Read my earlier articles

3. Send a text to the LCD Display

echo “Test” > /1-wire/FF.A30300000100/line20.0

If you get text on your LCD everything works

4. Use the script below as a template to get Nagios or op5 Monitor data to your LCD display. It is a modified nagios2lcd perl script.

I have put it in /etc/rc.local so it starts everytime my machine boots.

#!/usr/bin/perl
# +----------------------------------------------------------------------------+
# |                                StackSys                                    |
# |                         ron.sweeney@gmail.com                              |
# |                        http://www.stacksys.com                             |

# |----------------------------------------------------------------------------|
# | Modified by peter@it-slav.net
# | http://www.it-slav.net/blogs/
# |----------------------------------------------------------------------------|
# | FILE       : nagios2lcd.pl                                                 |
# | CLASS      : Toys                                                          |
# | PURPOSE    : Show nagios status on an lcdproc server.                      |
# | USAGE      : ./nagios2lcd.pl server port interval                          |
# | NOTE       : This script runs on versions 2.0 of Nagios (Tested on 2.01b)  |
# | RESOURCE   : Nagios(http://www.nagios.org) LCDPROC(http://www.lcdproc.org/)|
# +----------------------------------------------------------------------------+

#&usage if (! $ARGV[0]);
use OW;

my $owserver = "127.0.0.1:3001";
unless(OW::init($owserver)) {
 $status = $ERRORS{CRIT};
 $message = "OWServer not running at $owserver\n";
 exit $status;
}

while (true) {
&message;
}
sub message {

#@nagios = `/usr/local/nagios/bin/nagiostats`;
@nagios = `/opt/monitor/bin/nagiostats`;
foreach $line (@nagios) {

 if ($line =~m/Hosts Up\/Down\/Unreach/ ) {
 @hosts = split(/  +/, $line);

 @hostsvalues = split(/\//, $hosts[1]);

 $hostup = $hostsvalues[0];
 $hostdown = $hostsvalues[1];
 $hostunreach = $hostsvalues[2];
 $hostup =~s/ //g;
 $hostdown =~s/ //g;
 $hostunreach =~s/ //g;
 chop($hostunreach);
}
 elsif ($line =~m/Services Ok\/Warn\/Unk\/Crit/ ) {
 @services = split(/  +/, $line);

 @servicevalues = split(/\//, $services[1]);

 $serviceok = $servicevalues[0];
 $servicewarn = $servicevalues[1];
 $serviceunk = $servicevalues[2];
 $servicecrit = $servicevalues[3];

 $serviceok =~s/ //g;
 $servicewarn =~s/ //g;
 $serviceunk =~s/ //g;
 $servicecrit =~s/ //g;

 chop($servicecrit);

 }
 elsif ($line =~m/Status File Age:/ ) {
 @version = split(/  +/, $line);

 #@versionvalues = split(/  +/, $version[1]);
 $nagiosversion = $version[1];
 chop($nagiosversion);
 }
}

#Get indoor and outdoor temperatures
$tempinne = OW::get('10.04E060010800/temperature');
$tempinne =~ s/^\s*(.*?)\s*$/$1/;
$tempinne = sprintf("%.2f", $tempinne);

$tempute = OW::get('10.DEF05F010800/temperature');
$tempute =~ s/^\s*(.*?)\s*$/$1/;
$tempute = sprintf("%.2f", $tempute);

$datum=`/bin/date`;

OW::put('FF.A30300000100/line20.0','Temperatur');
OW::put('FF.A30300000100/line20.1',"PDC:     $tempinne\xdfC");
OW::put('FF.A30300000100/line20.2',"Outdoor: $tempute\xdfC");
#OW::put('FF.A30300000100/line20.3',"$datum");

for ($i=1;$i<5;$i++) {
 $datum=`/bin/date`;
 OW::put('FF.A30300000100/line20.3',"$datum");
 sleep (1);
}

my $gar="N/A";

OW::put('FF.A30300000100/line20.0'," ");
OW::put('FF.A30300000100/line20.1',"    It-Slav.net");
OW::put('FF.A30300000100/line20.2'," ");
#OW::put('FF.A30300000100/line20.3'," ");

for ($i=1;$i<5;$i++) {
 $datum=`/bin/date`;
 OW::put('FF.A30300000100/line20.3',"$datum");
 sleep (1);
}

#sleep(3);

#If any problem, flash the display
if ($hostdown!=0||$hostunreach>=1||$servicewarn!=0||$servicecrit>=1||$serviceunk>=1) {
 $blink=1;
 }
else {
 $blink=0;
}

OW::put('FF.A30300000100/line20.0','Op5 Monitor Status');
OW::put('FF.A30300000100/line20.1',"Host:U-$hostup D-$hostdown U-$hostunreach");
OW::put('FF.A30300000100/line20.2',"Serv:O-$serviceok W-$servicewarn ");
if ($servicecrit==0) {
 OW::put('FF.A30300000100/line20.3',"     C-$servicecrit  U-$serviceunk");
} else {
 OW::put('FF.A30300000100/line20.3',"     C-$servicecrit U-$serviceunk");
}

for($i=0;$i<=50;$i++) {
 if ($blink==1) {
 OW::put('FF.A30300000100/backlight','0');
 }
 OW::put('FF.A30300000100/backlight','1');
}

}

Read my previous articles to get the 1-wire bus up and running:

• 1-wire http://www.it-slav.net/blogs/?p=62
• 1-wire getting started http://www.it-slav.net/blogs/?p=67
• Temperature graphs http://www.it-slav.net/blogs/?p=75

I found a 1-wire temperature Nagios plugin on internet, but it had some disadvantages:

• Used Fahrenheit instead of Celsius
• Did not accept thresholds below zero degrees, in Sweden that is quite common temperature during winter.
• Strange License, it just said Copyright and a name and email address that bounced.

The Nagios plugin was written in Perl so it was straight forward to modify and fix the obstacles I found. But the copyright bothered me because I wanted to publish the changes, I tried to email the email address I found in the script but it bounced, so I decided to write my own plugin.

I have published the script at nagiosexchange.

The files

The plugin check_1-wiretemp version 1.0 can be found here or below.

#!/usr/bin/perl -w
#
# Check temperature of 1Wire device
# Requires use of owfs
#
# By Peter Andersson
# peter@it-slav.net
# http://www.it-slav.net/blogs/?p=115
# Licence GPLv2
# Version 1.0

use strict;
use Getopt::Std;
use OW;

my $owserver = "127.0.0.1:3001";
my(%ERRORS) = ( OK=>0, WARNING=>1, CRITICAL=>2, UNKNOWN=>3 );

my $temperature;
my $status=$ERRORS{OK};;
my $message;

my $debug_flag=0;

our($opt_c, $opt_w, $opt_W, $opt_C, $opt_h, $opt_o, $opt_i);

getopts("w:W:c:C:ho:i:");

sub printhelp () {
        print "Usage: check_1-wiretemp [-h] -c lowtempcritical -w lowtempwarning -W higtempwarning -C higtempcritical -i id [-o owserver:port]\n";
        print "-h Help, this text\n-c num Critical threshold for low temp\n-w num Warning threshold for low temp\n";
        print "-W num Warning threshold for hightemp\n-C num Critical threshold for hightemp\n";
        print "-o <name|ip>:port, Servername of 1-wire server and portnumber the owserver use, default 127.0.0.1:3001\n";
        print "-i 1-wire ID, i.e. 10.DEF05F01080015\n";
        print "\n\t\tby Peter Andersson\n\t\tpeter\@it-slav.net\n\t\thttp://www.it-slav.net/blogs/?p=115\n";
        if ($debug_flag) {
                print "opt_c:$opt_c opt_w:$opt_w opt_W:$opt_W opt_C:$opt_C opt_h:$opt_h owserver:$owserver opt_i:$opt_i Temperture:$temperature\n";
        }

        exit $status;
}

#sanity check
if (!defined $opt_c||!defined $opt_w||!defined $opt_W||!defined $opt_C||$opt_h) {
        $status= $ERRORS{UNKNOWN};
        &printhelp;
} elsif ($opt_c > $opt_w) {
        print "Critical low threshold must be higher or equal to warning low threshold\n";
        $status= $ERRORS{UNKNOWN};
        &printhelp;
} elsif ($opt_w > $opt_W || $opt_c > $opt_C) {
        print "Lower tresholds must be lower then higher thresholds\n";
        $status= $ERRORS{UNKNOWN};
        &printhelp;
} elsif ($opt_C < $opt_W) {
        print "Higher critical threshold must be higher or equal to higher warning threshold\n";
        $status= $ERRORS{UNKNOWN};
        &printhelp;
}

if ($opt_o) {
        $owserver = $opt_o;
}

unless(OW::init($owserver)) {
        $status = $ERRORS{CRIT};
        $message = "OWServer not running at $owserver\n";
        exit $status;
}
$temperature = OW::get("$opt_i/temperature");
$temperature =~ s/^\s*(.*?)\s*$/$1/; #remove whitespaces
unless (($temperature =~ /^-?(?:\d+(?:\.\d*)?|\.\d+)$/) || ($temperature =~ /^[+-]?\d+$/)) #check that it is an integer or decimal returned
{
        $message="Did not got an integer or a decimal from temperature probe";
        $status=$ERRORS{CRITICAL};
}
$temperature = sprintf("%.2f", $temperature);

if ($debug_flag) {
        print "opt_c:$opt_c opt_w:$opt_w opt_W:$opt_W opt_C:$opt_C opt_h:$opt_h owserver:$owserver opt_i:$opt_i Temperture:$temperature\n";
}

if ($temperature <= $opt_c) {
        $status=$ERRORS{CRITICAL};
        $message="CRITICAL";
} elsif ($temperature > $opt_c && $temperature <= $opt_w) {
        $status=$ERRORS{WARNING};
        $message="WARNING";
} elsif ($temperature >  $opt_w && $temperature <  $opt_W) {
        $status=$ERRORS{OK};
        $message="OK";
} elsif ($temperature >= $opt_W && $temperature < $opt_C) {
        $status=$ERRORS{WARNING};
        $message="WARNING";
} elsif ($temperature >= $opt_C) {
        $status=$ERRORS{CRITICAL};
        $message="CRITICAL";
} else { #This should never happend
        $status=$ERRORS{UNKNOWN};
        $message="UNKNOW";
}

print "$message: $temperature C\|temperature=$temperature;$opt_c;$opt_w;$opt_W;$opt_C\n";
exit $status;

The Metadata in op5 Monitor /opt/monitor/etc/checkcommands.cfg or Nagios checkcommands.cfg:

# command 'check_1-wiretemp'
define command{
    command_name                   check_1-wiretemp
    command_line                   $USER1$/custom/check_1-wiretemp -c $ARG1$ -w $ARG2$ -W$ARG3$ -C$ARG4$ -i $ARG5$ -o $ARG6$
    }

The service command definitions /opt/monitor/etc/services.cfg:

# service 'Temperature Outdoor'
define service{
    use                            default-service
    host_name                      monitor
    service_description            Temperature Outdoor
    check_command                  check_1-wiretemp!-20!-15!25!30!10.DEF05F01080015!127.0.0.1:3001
    contact_groups                 call_it-slav,it-slav_mail
    }

The graph map /opt/monitor/op5/nagiosgraph/map_custom/1-wiretemp.map:

# peter@it-slav.net
# http://www.it-slav.net/blogs/?p=115
# Service type: 1-wire-temperature
#   output: OK: 22.88 C
#   perfdata: temperature=2.56;-20;-15;25;30
/perfdata:temperature=(-?\d+.\d+);(-?\d+);(-?\d+);(-?\d+);(-?\d+)/
and push @s, [ temperature,
               [ "current", GAUGE, $1 ],
               [ "critical_low", GAUGE, $2 ],
               [ "warning_low", GAUGE, $3 ],
               [ "warning_high", GAUGE, $4 ],
               [ "critical_high", GAUGE, $5 ] ];

Step by step guide

Step by step guide for op5 Monitor users, Nagios (or op5 Monitor) users can copy and paste the information above to the configuration files:

1. Copy the plugin to the correct path, i.e. /opt/plugins/custom/

2. Test the plugin

[root@op5 custom]# ./check_1-wiretemp -c 0 -w 1 -W 20 -C 23 -i 10.DEF05F01080015
OK: 3.56 C|temperature=3.56;0;1;20;23

Yes it works!

3. Define the command in op5 Monitor (in Nagios edit the

configure->commands

Choose "Add new command"

Enter

command name: check_1-wiretemp

command line: $USER1$/custom/check_1-wiretemp -c $ARG1$ -w $ARG2$ -W$ARG3$ -C$ARG4$ -i $ARG5$ -o $ARG6$

Press Apply button

To test:

Press Test this command

Change $ARG1$ $ARG2$ and so on to:

/opt/plugins/custom/check_1-wiretemp -c 0 -w 1 -W20 -C23 -i 10.DEF05F01080015 -o 127.0.0.1:3001

Press continue

And the test works

Press "Save" to update the configuration files.

4. Configure the check_1-wiretemp

Press "Configure"

Pick the host, i.e. monitor

Press "Go"

Click "Services for monitor"

Choose "Add new service"

Service description i.e: Temperature Outdoor

check_command: check_1-wiretemp

check_command_args: -20!-15!25!30!10.DEF05F01080015!127.0.0.1:3001

(Critical low -20 C, Warning low -15 C, Warning high 25 C, Critical High 30 C, ID #10.DEF05F01080015, Host 127.0.0.1, port 3001)

Choose contact groups according to your preferences

To test, press "Test this service"

If everything looks fine press "Save" and your temperature service check is defined.

5. Create graphs

Copy and paste 1-wiretemp.map from above and put it in /opt/monitor/op5/nagiosgraph/map_custom/1-wiretemp.map

Congratulations, now you monitor your temperature and get alarms if it falls aout och thresholds.

Links

• Nagiosexchange
• op5 Monitor
• Nagios
• 1-wire

Here is the script that I’m using to read the temperatures, store the data in a round robin database and finally create the graphs.

#!/usr/bin/perl

# By Peter Andersson peter@it-slav.net

# rrd_tempsensor.pl

use RRDs;

use OW;

# define location of rrdtool databases

my $rrd = '/root/owfs/script/rrd_db';

# define location of images

my $img = '/home/peter/public_html/temps';

# process data for each interface (add/delete as required)

&ProcessSensor(0, "Temperatur i garaget", "127.0.0.1" , "3001" , "10.87507C010800");

&ProcessSensor(1, "Temperatur i PDCn", "op5.mynet",3001, "10.04E060010800");

&ProcessSensor(2, "Temperatur ute", "op5.mynet",3001,"10.DEF05F010800");

sub ProcessSensor

{

# process sensor

# inputs: $_[0]: sensor number (ie, 0/1/2/etc)

#         $_[1]: sensor description

        print "number:$_[0] desc:$_[1], server:$_[2] port:$_[3], id: $_[4]\n";

        my $owserver = "$_[2]:$_[3]";

        unless(OW::init($owserver)) {

            $status = $ERRORS{CRIT};

            $message = "OWServer not running at $owserver\n";

            exit $status;

        }

        # get temperature from sensor

        my $handle = OW::get("$_[4]/temperature");

#       print "handle=$handle\n";

        $handle =~ s/^\s*(.*?)\s*$/$1/;

        ## Check if input is an integer or decimal

        unless (($handle =~ /^-?(?:\d+(?:\.\d*)?|\.\d+)$/) || ($handle =~ /^[+-]?\d+$/))

        {

                print "Not an integer or a decimal\n";

                return($ERRORS{CRITICAL});

        }

        $temp=$handle;

        # remove eol chars

        chomp($temp);

        print "sensor $_[0]: $temp degrees C\n";

        # if rrdtool database doesn't exist, create it

        if (! -e "$rrd/temp$_[0].rrd")

        {

                print "creating rrd database for temp sensor $_[0]...\n";

                RRDs::create "$rrd/temp$_[0].rrd",

                        "-s 300",

                        "DS:temp:GAUGE:600:U:U",

                        "RRA:AVERAGE:0.5:1:2016",

                        "RRA:AVERAGE:0.5:6:1344",

                        "RRA:AVERAGE:0.5:24:2190",

                        "RRA:AVERAGE:0.5:144:3650";

        }

        if ($ERROR = RRDs::error) { print "$0: failed to create $_[0] database file: $ERROR\n"; }

        # check for error code from temp sensor

        if (int $temp eq 85)

        {

                print "failed to read value from sensor $_[0]\n";

        }

        else

        {

                # insert values into rrd

                RRDs::update "$rrd/temp$_[0].rrd",

                        "-t", "temp",

                        "N:$temp";

                if ($ERROR = RRDs::error) { print "$0: failed to insert $_[0] data into rrd: $ERROR\n"; }

        }

        # create graphs for current sensor

        &CreateGraph($_[0], "day", $_[1]);

        &CreateGraph($_[0], "week", $_[1]);

        &CreateGraph($_[0], "month", $_[1]);

        &CreateGraph($_[0], "year", $_[1]);

}

sub CreateGraph

{

# creates graph

# inputs: $_[0]: sensor number (ie, 0/1/2/etc)

#         $_[1]: interval (ie, day, week, month, year)

#         $_[2]: sensor description

        RRDs::graph "$img/temp$_[0]-$_[1].png",

                "-s -1$_[1]",

                "-t $_[2]",

                "-h", "150", "-w", "475",

                "-a", "PNG",

                "-v WWW.It-Slav.Net",

                "--slope-mode",

                "DEF:temp=$rrd/temp$_[0].rrd:temp:AVERAGE",

                "LINE2:temp#FF0000::",

                "CDEF:tempavarage=temp,86400,TREND",

                "LINE1:tempavarage#000088::",

                "GPRINT:temp:MIN:  Min\\: %6.1lf",

                "GPRINT:temp:MAX:  Max\\: %6.1lf",

                "GPRINT:temp:AVERAGE: Snitt\\: %6.1lf",

                "GPRINT:temp:LAST: Nuvarande\\: %6.1lf grader C\\n";

        if ($ERROR = RRDs::error) { print "$0: unable to generate sensor $_[0] $_[1] graph: $ERROR\n"; }

}

Use crontab to run it every 5 minutes:

*/5     *       *       *       *       /root/owfs/script/tempgraph.pl > /dev/null

To start the owfs server I put the following line in /etc/rc.local
/usr/sbin/owserver -u -C --usb_regulartime -p 3001

A good idea to browse the 1-wire bus is to use owhttp and a webbrowser. Start the owhttpd with
/usr/sbin/owhttpd -s localhost:3001 -p 12345
and use a webbrowser to cennect to http://the-host-that-is-running-owhttpd:12345

If you prefer to use files to communicate with the 1-wire bus start the owfs with
/usr/sbin/owfs -s localhost:3001 -m /1-wire

Now you can read the temperature by running
# cat /1-wire/10.DEF05F010800/temperature
4.4375

So now I know that the outdoor temperature is 4.4 degrees Celcius.

The first alternative, Sensatronic probes was to expensive for a project like this. After some investigation I stumbled over 1-wire technology and found an excellent shop in Sweden.